Beispiel

Ver0.1

Zusammen mit Theresa habe ich ein kleines Beispiel erstellt, dass gleichzeitig auch inkrementell und iterativ gebaut ist. Wir haben mit dem Minimum an Inform7 Text begonnen. Man braucht einen Raum, denn alles in Inform7 spielt sich in Raeumen ab. und ja, auch eine Wiese ist da ein Raum.

Wir haben also einen Raum gebaut und dann eine Regel, die egal  was man tut die Story direkt beendet. Das Produkt ist da also noch gar nicht schoen. aber es ist dennoch "fertig" und alle Arbeitsschritte bis zur lauffaehigen Website koennen durchlaufen werden.

"rats out of their walls" by theresa + ralf

cinema is a room. 

instead of doing anything, end the story.

Fertig, laeuft. Damit haben wir angefangen. Ihr koennt jeweils so einen Quell-Text-Kasten in der rechten, oberen Ecke beklicken. Das kopiert den ganzen Kasten mit dem Code. Diesen komplett in Inform7 eingefuegen und es kann auf "play" gedrueckt werden.

Ver0.2

Gemeinsam haben wir etwas herumgesponnen, was wohl in diesem Kino passieren koennte. Egal was, hauptsache es gibt ein paar mehr Handlungen, die zum Ende der Story fuehren.

"rats out of their walls" by theresa + ralf

cinema is a room. "This Cinema has red curtains all around. To west, you can see a restroom (unisex) and to the north is the exit out to the street."

restroom is west of cinema.

a pink elephant is in restroom.

a toilet is in restroom.

a toilet is a container. it is openable. it is open.

[instead of doing anything, end the story.]

flush button is a device. it is in restroom.

after switching on the flush button:
	if pink elephant is inside toilet:
		say "woosh, the pink elephant is gone.";
		now the pink elephant is in street;
	otherwise:
		say "wooosh".
		
		
street is a room. "A cold, windy street. No People. No Fun. Only Darkness. You like.".
street is north of cinema.

instead of going north in cinema:
	if pink elephant is in street:
		say "The pink Elephant doubled its size and looks veeeery angry at you.";
		say "The Pink Elephant toots the toilet water into your face. You dont like it.";
		End the Story;
	otherwise:
		now the player is in street.

sewers is a room. sewers is below restroom.

instead of going down in restroom:
	say "Yes, you still remember the scene from this movie and you dive down the toilet to explore the world underneath yours.";
	continue the action.

Ja, man kann einen pinken Elephant die Toilette runterspuelen und draussen auf der Strasse erwartet einen das Tier -> Ende.

Ver0.2-creative

Ich hatte Lust da weiter zu basteln. Ich habe mal ein paar Minuten einfach vor mit hintippen koennen und das Ergebnis war natuerlich weeiiit entfernt von meiner Vision, die ich hier noch nicht teilen moechte ;)

# rats

## and then the rats came out of their walls

You are inside a cinema. its full of smaller edible items, waiting to be collected. Your whole family can be fed by this large amount.

west of the audience hall big room thingy is a restroom. inside is a pink elephant. as you try to get it, its takes off his head and you can see an overheated human head.

[escape 1]
as you where aware that this human has indeed seen you, you escape the room down through the open toilet.

[escape 2]
instead of going east, back into the cinema you decided for speed and safety and dived down the toilet.

[sewers]
Next up you are in the safety of the sewers underneath the human buildings with your fur still wet.

to the north is the entrance where your family lives. warm and comfy, a nice place to dry yourself from your midnight swim down the toilet.

[instead going home]
As you wanted to enter your home, your wife was right in the door, handing over your backpack that you forgot to take with you to store all the stuff for the dinner tonight that you wanted to prepare.

[food hunt]
Ah, the dinner and the visitors. You almost forgot / verdraengt. Right. they expect a minimum of 3 courses. So vor, main, after course still missing.
So you decide not to enter to relax and instead to go back into the cinema to hunt for some food.

[quest]
You went back up into the restroom, which was pitch dark, but the light switched on while you openened the toilet deckel(?) west of the restroom you entered the cinema hall. and a welcoming smell of different types of pop corn welcomed you.

You can go west along the first row of chairs or south along the rows to have a view along the seats.

Das ist kein lauffaehiger Code, sondern eher so eine Idee, was der naechste Schritt sein koennte, um schonmal die Welt zu erweitern und fuer folgende Iterationen vorzubereiten. Daher hab ich das direkt genommen und lauffaehig gemacht.

Ver0.3

"rats out of their walls" by theresa + ralf

cinema is a room. "You are inside a cinema. Its full of edible items, waiting to be collected. Your whole family can be fed by this large amount. To the west, you can see a restroom (unisex) and to the north is the exit out to the street."

restroom is west of cinema.

a pink elephant is in restroom.

a toilet is in restroom.

a toilet is a container. it is openable. it is open.

[instead of doing anything, end the story.]

flush button is a device. it is in restroom.

instead of taking the pink elephant:
	say "As you try to get it, its takes off his head and you can see an overheated human head instead. As you were aware that this human has indeed seen you, you escape the room down through the open toilet.";
	now the player is in sewers.



after switching on the flush button:
	if pink elephant is inside toilet:
		say "woosh, the pink elephant is gone.";
		now the pink elephant is in street;
	otherwise:
		say "wooosh".
		
		
street is a room. "A cold, windy street. No People. No Fun. Only Darkness. You like.".
street is north of cinema.

instead of going north in cinema:
	if pink elephant is in street:
		say "The pink Elephant doubled its size and looks veeeery angry at you.";
		say "The Pink Elephant toots the toilet water into your face. You dont like it.";
		End the Story;
	otherwise:
		now the player is in street.

[TODO first time, during wetness...]
sewers is a room. the description is "Next up you are in the safety of the sewers underneath the human buildings with your fur still wet.".

sewers is below restroom.

home is a room.
home is north of sewers.

the rucksack is a container. the rucksack is wearable.
understand "sack", "backpack" as the rucksack.

instead of going north in sewers:
	say "As you wanted to enter your home, your wife was right in the door, handing over your backpack that you forgot to take with you to store all the stuff for the dinner tonight that you wanted to prepare.
	[paragraph break]
	Ah, the dinner and the visitors. You almost forgot / verdraengt. Right. they expect a minimum of 3 courses. So vor, main, after course still missing.
So you decide not to enter to relax and instead to go back into the cinema to hunt for some food. ";
	now the player wears the rucksack;
	say "You went back up into the restroom, which was pitch dark, but the light switched on while you openened the toilet deckel(?) west of the restroom you entered the cinema hall. and a welcoming smell of different types of pop corn welcomed you.

You can go west along the first row of chairs or south along the rows to have a view along the seats.";
	now the player is in cinema.

instead of going down in restroom:
	say "Yes, you still remember the scene from this movie and you dive down the toilet to explore the world underneath yours.";
	continue the action.

laeuft schonmal, aber sehr inkonsistent. Da wird immermal was beschrieben, was so nicht sein kann. Der Spieler kann auch statt durchs Klo ueber die Strasse nach Hause gelangen zb. nach etwas aufraeumen sah es dann so aus:

Ver0.4

"and then the rats came out of their walls" by theresa + ralf

chapter setup

prolog is a scene. prolog begins when play begins.
quest is a scene. quest begins when prolog ends.
quest ends when dinner-count is three.

when quest ends:
	say "Now you are well prepared to get that dinner started. You are heading home.";
	end the story.

quest-start is a truth state that varies. quest-start is false.
prolog ends when quest-start is true.

dinner-count is a number that varies. dinner-count is zero.

the player wears your fur.
instead of dropping your fur, say "Thats part of your body!".


cinema is a room. "You are inside a cinema. [if quest is happening]Its full of edible items, waiting to be collected. Your whole family can be fed by this large amount. [end if]To the west, you can see a restroom (unisex) and to the north is the exit out to the street."

restroom is west of cinema.

a pink elephant is in restroom.

a toilet is in restroom.

a toilet is a container. it is openable. it is open.

[instead of doing anything, end the story.]

flush button is a device. it is in restroom.

instead of taking the pink elephant:
	say "As you try to get it, its takes off his head and you can see an overheated human head instead. As you were aware that this human has indeed seen you, you escape the room down through the open toilet.";
	now the pink elephant is off-stage;
	now the player is in sewers.



after switching on the flush button:
	if pink elephant is inside toilet:
		say "woosh, the pink elephant is gone.";
		now the pink elephant is in street;
	otherwise:
		say "wooosh".
		
		
street is a room. "A cold, windy street. No People. No Fun. Only Darkness. You like. Additionally there is an inviting manhole leading downwards. To the south is the entrance back into the cinema.".
street is north of cinema.

instead of going north in cinema:
	if pink elephant is in street:
		say "The pink Elephant doubled its size and looks veeeery angry at you.";
		say "The Pink Elephant toots the toilet water into your face. You dont like it.";
		End the Story;
	otherwise:
		now the player is in street.

front row east is a room. the description is "You can go south into a darker corner or west in the direction of the restroom.".
along the rows is a room. the description is "You can go east into a darker corner or north in the direction of the restroom.".
darker corner is a room. the description is "You can go north to the front row or west along the rows.".
front row east is east of cinema.
along the rows is south of cinema.
darker corner is east of along the rows.
darker corner is south of front row east.

instead of going east in cinema during prolog, say "You would rather rest at home than put yourself in danger at the moment.".
instead of going south in cinema during prolog, say "You would rather rest at home than put yourself in danger at the moment.".

[TODO first time, during wetness...]
sewers is a room. the description is "Next up you are in the safety of the sewers underneath the human buildings. To the north is the hole leading to your home. Against the flow to southeast it leads to the sewers underneath the street.".

sewers is below restroom.

street sewers is below street. the description is "The flow leads southwest closer to your home or up to the street.".
street sewers is northeast of sewers.

home is a room.
home is north of sewers.

[the rucksack is a container. the rucksack is wearable.]
the rucksack is a player's holdall and wearable.
understand "sack", "backpack" as the rucksack.

instead of going north in sewers:
	say "As you wanted to enter your home, your partner was right in the door, handing over your backpack that you forgot to take with you to store all the stuff for the dinner tonight that you wanted to prepare.
	[paragraph break]
	Ah, the dinner and the visitors. You almost forgot. Right, they expect a minimum of 3 courses. So a minimum of starters, main course and dessert.
So you decide not to enter to relax and instead to go back into the cinema to hunt for some food. ";
	now the player wears the rucksack;
	say "You went back up into the restroom, which was pitch dark, but the light switched on while you openened the toilet lid.";
	now the player is in restroom;
	now quest-start is true.

instead of going down in restroom:
	say "Yes, you still remember the scene from this movie and you dive down the toilet to explore the world underneath yours.";
	continue the action.

instead of going east in restroom during quest:
	say "You entered the cinema hall to the west and a welcoming smell of different types of pop corn welcomed you.";
	continue the action.

bucket full of chicken wings is in darker corner.
caramel popcorn is in front row east.
a bottle of whisky is in along the rows.


after taking the caramel popcorn:
	increment dinner-count;
	continue the action.
after taking bucket full of chicken wings:
	increment dinner-count;
	continue the action.
after taking a bottle of whisky:
	increment dinner-count;
	continue the action.

Release along with an interpreter, a website.

Auf diese Weise hatte ich eine Aufgabe mit drei Teilen drin, die man erfuellen kann und zum "Ende" fuehren. Da die Puzzle-Baum Technik hinten anfaengt, ist so auch das vermeintliche Ende schon erreicht und kann durch zusaetzliche Raetsel ein klein wenig unlangweiliger gemacht werden.

Das passiert aber spaeter....vielleicht ;)